Volume 13 - Shrines (Part 2)
Book 1 - Describing Shrine Interiors
Part 1 - Shrine Statues (Revisited)
The monster-head list is a list of monster names that varies. The monster-head list is {}.
The jewel-type list is a list of adjectives that varies. The jewel-type list is {amethyst, aquamarine, obsidian, ruby, garnet, emerald, sapphire, diamond, opal, topaz}.
A hand is a kind of container. A hand is part of every shrine statue. Understand "marble" as a hand. Understand "man" as a hand when the item described is male. Understand "woman" as a hand when the item described is female. Understand "gem", "gems", "jewel", "jewels", "eye", and "eyes" as a hand when a shrine statue in the location encloses an orb. [For reasons I completely don't understand, I can't stick all this to the statue itself.]
Before doing something when the noun is a hand:
now the noun is a random shrine statue in the location;
try the current action instead.
Before doing something when the second noun is a hand:
now the second noun is a random shrine statue in the location;
try the current action instead.
A shrine statue has an adjective called the statue adjective. Understand the statue adjective property as describing a shrine statue.
A shrine statue has an adjective called the color. Understand the color property as describing a shrine statue.
A shrine statue has an adjective called the jewel-type. Understand the jewel-type property as describing a shrine statue when the item described encloses an orb.
A shrine statue has a monster name called the statue-head. Understand the statue-head property as describing a shrine statue. A shrine statue can be male or female. A shrine statue is usually male.
Rule for printing the name of a shrine statue (called the target statue):
if the target statue is known:
say "statue of [shrine deity of the target statue]";
otherwise if the target statue is Perceived:
say "[color of the target statue] marble statue";
otherwise:
say "[statue-head]-headed statue".
The Perceived adjective list is a list of adjectives that varies. The Perceived adjective list is {stately, graceful, lithe, colossal, huge, immense, exquisite, artistic}.
The Unperceived adjective list is a list of adjectives that varies. The Unperceived adjective list is {crude, unsettling, sinister, unpleasant, baleful, disquieting, malevolent}.
The statue color list is a list of adjectives that varies. The statue color list is {pure white, ivory, white, pink, grey, blue-grey, greyish white, yellowish, brownish, yellowish-white, green, blue, black, spotted, striated, striped}.
Instead of examining a shrine statue:
if the location is Perceived:
say "This [statue adjective of the noun] [if the noun is male]man[otherwise]woman[end if] has been carved from [color of the noun] marble. ";
otherwise:
say "This [statue adjective of the noun] [statue-head of the noun]-headed [if the noun is male]man[otherwise]woman[end if] has been carved from [color of the noun] marble. ";
if an orb is in the noun:
say "The [statue-head of the noun]'s eyes are twin pieces of [jewel-type of the noun].[paragraph break]";
otherwise:
say "The [if the noun is male]man[otherwise]woman[end if]'s eyes are closed.[paragraph break]";
if the noun contains an orb (called the target orb):
say "In one hand, the statue holds [a target orb].";
otherwise:
say "One of the statue's hands is outstretched and empty[first time][if the player has an orb]. The orb in your hand flashes faintly, drawing your attention[end if][only].";
To describe the shrine statue: [This doesn't actually get called until the monsters are over.]
add the appropriate monster name list of the ungulate-shape to the monster-head list;
add the appropriate monster name list of the feline-shape to the monster-head list;
add the appropriate monster name list of the winged-shape to the monster-head list;
sort the monster-head list in random order;
now the statue-head of the current statue is entry 1 of the monster-head list;
sort the jewel-type list in random order;
now the jewel-type of the current statue is entry 1 of the jewel-type list;
if a random chance of 1 in 2 succeeds:
now the current statue is female;
otherwise:
now the current statue is male;
if the current statue is Perceived:
sort the Perceived adjective list in random order;
now the statue adjective of the current statue is entry 1 of the Perceived adjective list;
otherwise:
sort the Unperceived adjective list in random order;
now the statue adjective of the current statue is entry 1 of the Unperceived adjective list;
sort the statue color list in random order;
now the color of the current statue is entry 1 of the statue color list;
DM "Now the statue of [shrine deity of the current statue] is a [statue adjective of the current statue] [statue-head of the current statue]-headed [if the current statue is male]man[otherwise]woman[end if] carved from [color of the current statue] marble."
Rule for writing a paragraph about a shrine statue (called the target statue):
say "At the center of the shrine, there stands a ";
if the location is Perceived:
if the target statue is known:
say "[statue adjective of the target statue] statue of [shrine deity of the target statue]";
otherwise:
say "[statue adjective of the target statue] [color of the target statue] marble statue";
otherwise:
if the target statue is known:
say "[statue adjective of the target statue] statue of [shrine deity of the target statue], represented in the form of a [statue-head of the target statue]-headed [if the target statue is male]man[otherwise]woman[end if]";
otherwise:
say "[statue adjective of the target statue] [statue-head of the target statue]-headed statue";
if the target statue encloses an orb (called the target orb):
say ".[paragraph break]The statue holds a shining [target orb] in one hand";
if the location encloses a lit candle set:
say ".";
otherwise:
say ", but the orb's light isn't strong enough to illuminate the shrine's interior.";
otherwise:
say ".".