A cave is a kind of room.
There is a cave called Low N/S Passage. 

Dwarf-count is a number that varies. Dwarf-count is 5.

A threatening little dwarf is a man.

A nasty little axe is a thing.

Every turn when the location of the player is a cave and dwarf-count > 0:
	if a random chance of 1 in 2 succeeds and the dwarf is not in the location of the player:
		now dwarf-count is dwarf-count - 1;
		now the dwarf is in the location of the player;
		say "A threatening little dwarf comes out of the shadows!";
		if the nasty little axe is nowhere:
			the dwarf throws the axe in 1 turn from now.

At the time when the dwarf throws the axe:
	say "The dwarf throws a nasty little axe at you, misses, curses, and runs away.";
	move the axe to the location of the player;
	remove the dwarf from play.
	
Every turn when the dwarf is somewhere:
	if the location of the dwarf is not the location of the player:
		say "The dwarf stalks after you...";
		move the dwarf to the location of the player;
	if the axe is somewhere and a random chance of 3 in 4 succeeds:
		say "The dwarf throws a nasty little knife at you, ";
		if a random chance of 95 in 1000 succeeds:
			say "and hits!";
			end the story saying "It looks as though you're dead. I think we'll just call it a day.";
		else:
			say "but misses!";
	if a random chance of 1 in 3 succeeds:
		say "Tiring of this, the dwarf slips away.";
		remove the dwarf from play.
	
Instead of throwing the nasty little axe at the dwarf:
	move the axe to the location of the player;
	if a random chance of 2 in 3 succeeds:
		remove the dwarf from play;
		say "You killed a little dwarf! The body vanishes in a cloud of greasy black smoke.";
	else:
		say "Missed! The little dwarf dodges out of the way of the axe."